Hi Michael ,
As I understand that you want to save your standard text after changing text inside of popup editor. Check the following code. It will probably answer your question.
DATA : GS_HEADER TYPE THEAD .
DATA : GT_TEXT TYPE TABLE OF TLINE ,
GS_TEXT TYPE TLINE .
DATA : GT_TEXT_IMP TYPE TABLE OF TDLINE ,
GS_TEXT_IMP TYPE TDLINE.
GS_HEADER-TDID = 'ST'.
GS_HEADER-TDSPRAS = SY-LANGU.
GS_HEADER-TDNAME = 'ZTEXT_EXAMPLE'.
GS_HEADER-TDOBJECT = 'TEXT'.
CALL FUNCTION 'READ_TEXT'
EXPORTING
ID = GS_HEADER-TDID
LANGUAGE = GS_HEADER-TDSPRAS
NAME = GS_HEADER-TDNAME
OBJECT = GS_HEADER-TDOBJECT
TABLES
LINES = GT_TEXT
EXCEPTIONS
ID = 1
LANGUAGE = 2
NAME = 3
NOT_FOUND = 4
OBJECT = 5
REFERENCE_CHECK = 6
WRONG_ACCESS_TO_ARCHIVE = 7
OTHERS = 8.
LOOP AT GT_TEXT INTO GS_TEXT.
CLEAR : GS_TEXT_IMP.
GS_TEXT_IMP = GS_TEXT-TDLINE.
APPEND GS_TEXT_IMP TO GT_TEXT_IMP.
ENDLOOP.
CALL FUNCTION 'TERM_CONTROL_EDIT'
EXPORTING
TITEL = 'Hello Friends!'
LANGU = GS_HEADER-TDSPRAS
TABLES
TEXTLINES = GT_TEXT_IMP
EXCEPTIONS
USER_CANCELLED = 1
OTHERS = 2.
IF SY-SUBRC = 0.
REFRESH : GT_TEXT.
LOOP AT GT_TEXT_IMP INTO GS_TEXT_IMP.
CLEAR : GS_TEXT.
GS_TEXT-TDFORMAT = '*'.
GS_TEXT-TDLINE = GS_TEXT_IMP.
APPEND GS_TEXT TO GT_TEXT.
ENDLOOP.
CALL FUNCTION 'SAVE_TEXT'
EXPORTING
HEADER = GS_HEADER
SAVEMODE_DIRECT = 'X'
TABLES
LINES = GT_TEXT
EXCEPTIONS
ID = 1
LANGUAGE = 2
NAME = 3
OBJECT = 4
OTHERS = 5.
Regards
Sapromancer